You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.

193 lines
5.9KB

  1. QT -= gui
  2. TARGET = GPSBabel
  3. CONFIG += console
  4. CONFIG -= app_bundle
  5. CONFIG += c++11
  6. TEMPLATE = app
  7. MINIMAL_FMTS = magproto.cc explorist_ini.cc gpx.cc geo.cc mapsend.cc mapsource.cc garmin.cc \
  8. garmin_device_xml.cc garmin_tables.cc internal_styles.cc nmea.cc \
  9. kml.cc wbt-200.cc
  10. ALL_FMTS=$$MINIMAL_FMTS gtm.cc gpsutil.cc pcx.cc \
  11. skytraq.cc holux.cc tmpro.cc tpg.cc tpo.cc \
  12. xcsv.cc tiger.cc easygps.cc \
  13. saroute.cc navicache.cc psitrex.cc delgpl.cc \
  14. ozi.cc text.cc html.cc netstumbler.cc \
  15. igc.cc brauniger_iq.cc shape.cc hiketech.cc glogbook.cc \
  16. vcf.cc xhtmlent.cc lowranceusr.cc an1.cc tomtom.cc \
  17. tef_xml.cc maggeo.cc vitosmt.cc gdb.cc bcr.cc \
  18. ignrando.cc stmwpp.cc cst.cc nmn4.cc compegps.cc \
  19. yahoo.cc unicsv.cc wfff_xml.cc garmin_txt.cc gpssim.cc \
  20. stmsdf.cc gtrnctr.cc dmtlog.cc raymarine.cc alan.cc vitovtt.cc \
  21. ggv_log.cc g7towin.cc garmin_gpi.cc lmx.cc random.cc xol.cc dg-100.cc \
  22. navilink.cc mtk_logger.cc ik3d.cc osm.cc destinator.cc exif.cc vidaone.cc \
  23. igo8.cc gopal.cc humminbird.cc mapasia.cc gnav_trl.cc navitel.cc ggv_ovl.cc \
  24. jtr.cc sbp.cc sbn.cc mmo.cc skyforce.cc itracku.cc v900.cc \
  25. pocketfms_bc.cc pocketfms_fp.cc pocketfms_wp.cc naviguide.cc enigma.cc \
  26. vpl.cc teletype.cc jogmap.cc bushnell.cc bushnell_trl.cc wintec_tes.cc \
  27. subrip.cc garmin_xt.cc garmin_fit.cc lowranceusr4.cc \
  28. mtk_locus.cc googledir.cc mapbar_track.cc mapfactor.cc f90g_track.cc \
  29. energympro.cc mynav.cc ggv_bin.cc globalsat_sport.cc geojson.cc
  30. DEPRECIATED_FMTS=cetus.cc copilot.cc gpspilot.cc magnav.cc psp.cc gcdb.cc quovadis.cc gpilots.cc geoniche.cc palmdoc.cc hsa_ndv.cc coastexp.cc pathaway.cc coto.cc msroute.cc mag_pdb.cc axim_gpb.cc delbin.cc google.cc
  31. DEPRECIATED_HEADERS=geo.h quovadis.h
  32. DEPRECIATED_SHAPE=pdbfile.cc
  33. # ALL_FMTS=$$MINIMAL_FMTS
  34. FILTERS=position.cc radius.cc duplicate.cc arcdist.cc polygon.cc smplrout.cc \
  35. reverse_route.cc sort.cc stackfilter.cc trackfilter.cc discard.cc \
  36. nukedata.cc interpolate.cc transform.cc height.cc swapdata.cc bend.cc \
  37. validate.cc
  38. SHAPE=shapelib/shpopen.c shapelib/dbfopen.c shapelib/safileio.c
  39. ZLIB=zlib/adler32.c zlib/compress.c zlib/crc32.c zlib/deflate.c zlib/inffast.c \
  40. zlib/inflate.c zlib/infback.c zlib/inftrees.c zlib/trees.c \
  41. zlib/uncompr.c zlib/gzlib.c zlib/gzclose.c zlib/gzread.c \
  42. zlib/gzwrite.c zlib/zutil.c
  43. JEEPS += jeeps/gpsapp.cc jeeps/gpscom.cc \
  44. jeeps/gpsmath.cc jeeps/gpsmem.cc \
  45. jeeps/gpsprot.cc jeeps/gpsread.cc \
  46. jeeps/gpsdevice.cc jeeps/gpsdevice_ser.cc jeeps/gpsdevice_usb.cc \
  47. jeeps/gpsrqst.cc jeeps/gpssend.cc jeeps/gpsserial.cc jeeps/jgpsutil.cc \
  48. jeeps/gpsusbread.cc jeeps/gpsusbsend.cc \
  49. jeeps/gpsusbcommon.cc
  50. SUPPORT = queue.cc route.cc waypt.cc filter_vecs.cc util.cc vecs.cc mkshort.cc \
  51. csv_util.cc strptime.c grtcirc.cc util_crc.cc xmlgeneric.cc \
  52. formspec.cc xmltag.cc cet.cc cet_util.cc fatal.cc rgbcolors.cc \
  53. inifile.cc garmin_fs.cc gbsleep.cc units.cc gbser.cc \
  54. gbfile.cc parse.cc session.cc main.cc globals.cc \
  55. src/core/usasciicodec.cc \
  56. src/core/xmlstreamwriter.cc
  57. HEADERS = \
  58. an1sym.h \
  59. cet.h \
  60. cet/ansi_x3_4_1968.h \
  61. cet/cp1252.h \
  62. cet/iso_8859_8.h \
  63. cet_util.h \
  64. csv_util.h \
  65. defs.h \
  66. explorist_ini.h \
  67. filterdefs.h \
  68. garmin_device_xml.h \
  69. garmin_fs.h \
  70. garmin_gpi.h \
  71. garmin_tables.h \
  72. gbfile.h \
  73. gbser.h \
  74. gbser_private.h \
  75. gbversion.h \
  76. grtcirc.h \
  77. height.h \
  78. holux.h \
  79. inifile.h \
  80. jeeps/garminusb.h \
  81. jeeps/gps.h \
  82. jeeps/gpsapp.h \
  83. jeeps/gpscom.h \
  84. jeeps/gpsdatum.h \
  85. jeeps/gpsdevice.h \
  86. jeeps/gpsfmt.h \
  87. jeeps/gpsinput.h \
  88. jeeps/gpsmath.h \
  89. jeeps/gpsmem.h \
  90. jeeps/gpsport.h \
  91. jeeps/gpsproj.h \
  92. jeeps/gpsprot.h \
  93. jeeps/gpsread.h \
  94. jeeps/gpsrqst.h \
  95. jeeps/gpssend.h \
  96. jeeps/gpsserial.h \
  97. jeeps/gpsusbcommon.h \
  98. jeeps/gpsusbint.h \
  99. jeeps/gpsutil.h \
  100. magellan.h \
  101. mapsend.h \
  102. navilink.h \
  103. queue.h \
  104. session.h \
  105. shapelib/shapefil.h \
  106. strptime.h \
  107. xmlgeneric.h \
  108. zlib/crc32.h \
  109. zlib/deflate.h \
  110. zlib/inffast.h \
  111. zlib/inffixed.h \
  112. zlib/inflate.h \
  113. zlib/inftrees.h \
  114. zlib/trees.h \
  115. zlib/zconf.h \
  116. zlib/zconf.in.h \
  117. zlib/zlib.h \
  118. zlib/zutil.h \
  119. src/core/xmlstreamwriter.h \
  120. src/core/logging.h
  121. SUBDIRS += jeeps
  122. macx|linux {
  123. DEFINES += HAVE_NANOSLEEP HAVE_LIBUSB HAVE_GLOB
  124. SOURCES += gbser_posix.cc
  125. JEEPS += jeeps/gpslibusb.cc
  126. INCLUDEPATH += jeeps
  127. }
  128. win32 {
  129. DEFINES += __WIN32__ _CONSOLE
  130. DEFINES -= UNICODE ZLIB_INHIBITED
  131. CONFIG(debug, debug|release) {
  132. DEFINES += _DEBUG
  133. }
  134. SOURCES += gbser_win.cc
  135. JEEPS += jeeps/gpsusbwin.cc
  136. LIBS += "C:/Program Files/Windows Kits/8.0/Lib/win8/um/x86/setupapi.lib" "C:/Program Files/Windows Kits/8.0/Lib/win8/um/x86/hid.lib"
  137. }
  138. win32-msvc*{
  139. DEFINES += _CRT_SECURE_NO_DEPRECATE
  140. INCLUDEPATH += ../../src/core src/core
  141. QMAKE_CXXFLAGS += /MP -wd4100
  142. TEMPLATE=vcapp
  143. }
  144. linux {
  145. DEFINES += HAVE_LINUX_HID
  146. }
  147. macx {
  148. LIBS += -framework IOKit -framework CoreFoundation
  149. INCLUDEPATH += mac/libusb
  150. SOURCES += mac/libusb/darwin.c \
  151. mac/libusb/descriptors.c \
  152. mac/libusb/error.c \
  153. mac/libusb/usb.c
  154. }
  155. SOURCES += $$ALL_FMTS $$FILTERS $$SUPPORT $$SHAPE $$ZLIB $$JEEPS
  156. DEFINES += NEW_STRINGS
  157. # We don't care about stripping things out of the build. Full monty, baby.
  158. DEFINES += MAXIMAL_ENABLED
  159. DEFINES += FILTERS_ENABLED
  160. DEFINES += PDBFMTS_ENABLED
  161. DEFINES += SHAPELIB_ENABLED
  162. DEFINES += CSVFMTS_ENABLED
  163. DEFINES += CET_WANTED
  164. # Creator insists on adding -W to -Wall which results in a completely
  165. # absurd amount of jibber-jabber on perfectly legally formed code.
  166. # Rather than wade through a thousand lines of yammer, let's just nuke -W
  167. # but leave -Wall, which actually has useful stuff.
  168. # Citation: http://stackoverflow.com/questions/18667291/disable-wall-compiler-warnings-in-a-qt-project
  169. QMAKE_CFLAGS_WARN_ON -= -W
  170. QMAKE_CXXFLAGS_WARN_ON -= -W